Tuske 애드온인것 같은데, 해당 애드온은 1.10버전까지만 지원합니다.
1.13부터 인벤토리 api가 많이 바뀌어서 호환이 안되는 것일 수 있습니다.
GUI 제작은 애드온 없어도 됩니다.

on load:
    # 메뉴GUI 아이템 세팅
    set {_slot::4} to block of gold named "&a거주구역 메뉴열기"
    set lore of {_slot::4} to "&7거주구역에 대한 메뉴화면입니다"
    loop {_slot::*}:
        set {gui::menu::slot::%loop-index%} to loop-value
    clear {_slot::*}


    # 구역GUI 아이템 세팅
    set {_slot::11} to ender eye named "&2거주지 만들기"
    set lore of {_slot::11} to "&7첫 거주지를 생성합니다"
    set {_slot::13} to oak door named "&2자신의 거주지로 이동"
    set lore of {_slot::13} to "&7자신의 소유자로 이동합니다"
    set {_slot::15} to ender eye named "&2거주지로 이동"
    set lore of {_slot::15} to "&7거주지로 이동합니다"
    loop {_slot::*}:
        set {gui::region::slot::%loop-index%} to loop-value
    clear {_slot::*}


on unload:
    #GUI 아이템 초기화
    delete {gui::*}


command /?:
    trigger:
        # 메뉴GUI 열기
        set {_inv} to chest inventory with 1 rows named "    &1&l메뉴화면"
        loop {gui::menu::slot::*}:
            set {_slot} to loop-index parsed as integer
            set slot {_slot} of {_inv} to loop-value
        open {_inv} to player


on inventory click:
    # 슬롯 판단
    clicked slot is {gui::menu::slot::4}
    cancel event
    
    # 구역GUI 열기
    set {_inv} to chest inventory with 3 rows named "    &2&l거주구역"
    loop {gui::region::slot::*}:
        set {_slot} to loop-index parsed as integer
        set slot {_slot} of {_inv} to loop-value
    open {_inv} to player