이러면되요

command /원하는명령어이름보조:
  trigger:
    execute player command "/원하는명령어이름"


command /원하는명령어이름:
  trigger:
    {티피::%uuid of player%} is not set
    send title "&c3" with subtitle "초 후 스폰으로 이동됩니다" to player for 1.5 seconds with fade in 2 tick and fade out 5 tick
    set {티피::%uuid of player%} to location of player
    while {티피::%uuid of player%} is set:
      add 1 to {_time}
      if {_time} >= 3*20:
        delete {티피::%uuid of player%}
        teleport player to location(x좌표,y좌표,z좌표,world "월드이름")
        send title "&6&l스폰" with subtitle "텔레포트 하였습니다" to player for 1.5 seconds with fade in 2 tick and fade out 5 tick
        stop this loop
      else if mod({_time},20) = 0:
        send title "&c%3-floor({_time}/20)%" with subtitle "초 후 스폰으로 이동됩니다" to player for 1.5 seconds with fade in 2 tick and fade out 5 tick
      wait 1 tick


on player move:
  {티피::%uuid of player%} is set
  distance between player and {티피::%uuid of player%} > 1
  delete {티피::%uuid of player%}

이미 위에서 알려드렸지만

스크립트 구문을 처음 접해 보는거라면 유튜브를 보고 연습하시는걸 추천드립니다

다른 분들이 다 알려드리면 연습이 되지 않아서..ㅎㅎ 거의 다 유튜브 찾아보시면 스크립트 강좌로 알려줍니다!